# Maintainer: Maksim Bondarenkov <maksapple2306@gmail.com>

_realname=pygls
pkgbase=mingw-w64-python-${_realname}
pkgname=("${MINGW_PACKAGE_PREFIX}-python-${_realname}")
pkgver=1.3.1
pkgrel=3
pkgdesc="A pythonic generic language server (mingw-w64)"
arch=('any')
mingw_arch=('mingw64' 'ucrt64' 'clang64' 'clangarm64')
msys2_references=(
  'archlinux: python-pygls'
  'purl: pkg:pypi/pygls'
)
msys2_repository_url='https://github.com/openlawlibrary/pygls/'
url='https://pygls.readthedocs.io/'
license=('spdx:Apache-2.0')
depends=("${MINGW_PACKAGE_PREFIX}-python-cattrs"
         "${MINGW_PACKAGE_PREFIX}-python-lsprotocol")
makedepends=("${MINGW_PACKAGE_PREFIX}-python-build"
             "${MINGW_PACKAGE_PREFIX}-python-installer"
             "${MINGW_PACKAGE_PREFIX}-python-poetry-core")
checkdepends=("${MINGW_PACKAGE_PREFIX}-python-pytest-asyncio")
source=("https://pypi.org/packages/source/${_realname::1}/${_realname}/${_realname}-${pkgver}.tar.gz"
        "001-bump-lsprotocol.patch")
sha256sums=('140edceefa0da0e9b3c533547c892a42a7d2fd9217ae848c330c53d266a55018'
            '646bbf07fd6b8d79f02653c26627aeda5742c305d27e6bc33b559d813a1930d1')

prepare() {
  cd "${_realname}-${pkgver}"

  patch -Np1 -i ../001-bump-lsprotocol.patch
}

build() {
  cp -r "${_realname}-${pkgver}" "python-build-${MSYSTEM}" && cd "python-build-${MSYSTEM}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

check() {
  cd "python-build-${MSYSTEM}"

  python -m pytest || warning "Tests failed"
}

package() {
  cd "python-build-${MSYSTEM}"

  MSYS2_ARG_CONV_EXCL="--prefix=" \
    python -m installer --prefix=${MINGW_PREFIX} \
    --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE.txt "${pkgdir}${MINGW_PREFIX}/share/licenses/python-${_realname}/LICENSE"
}
